guest: add 64bit guest to toy with msrHEADmain

Guest to toy with msr register and the swapgs instruction.

3 files changed, 100 insertions, 7 deletions

diff --git a/guest/Makefile b/guest/Makefile
index 635759a..61d7790 100644
--- a/guest/Makefile
+++ b/guest/Makefile
@@ -1,14 +1,16 @@
 ARCH16 := i8086
 ARCH64 := i386:x86-64
 
-guest: guest16 guest64
-disasm: disasm16 disasm64
+bits = $(word 1, $(subst -, ,$(1)))
+
+guest: guest16 guest64 guest64-msr
+disasm: disasm16 disasm64 disasm64-msr
 
 guest%: guest.ld guest%.S
-	$(CC) $(CFLAGS) -m$* -o $@ -nostdlib -ffreestanding -Wpedantic -Wall -Wextra -Werror -T guest.ld guest$*.S
+	$(CC) $(CFLAGS) -m$(call bits, $*) -o $@ -nostdlib -ffreestanding -Wpedantic -Wall -Wextra -Werror -T guest.ld guest$*.S
 
 disasm%: guest%
-	objdump -D -b binary -m $(ARCH$*) -M intel $^
+	objdump -D -b binary -m $(ARCH$(call bits, $*)) -M intel $^
 
 clean:
-	$(RM) guest16 guest64
+	$(RM) guest16 guest64 guest64-msr
diff --git a/guest/guest64-msr.S b/guest/guest64-msr.S
new file mode 100644
index 0000000..8e7d4a4
--- /dev/null
+++ b/guest/guest64-msr.S
@@ -0,0 +1,91 @@
+.intel_syntax noprefix
+
+// Define a string literal.
+.macro defstr name str
+\name:
+    .ascii "\str"
+\name\()_len:
+    .8byte . - \name
+.endm
+
+// Print a string literal.
+.macro pstr name
+    mov dx, 0x42                   // Magic IO port for strings.
+    lea rsi, [rip + \name]         // Address of string.
+    mov rcx, [rip + \name\()_len]  // Len of string.
+    rep outsb                      // Write ds:rsi to output port rdx.
+.endm
+
+.section .boot, "ax", @progbits
+    // -- SWAPGS test -----------------------------------------------------------
+
+    // Setup IA32_GS_BASE.
+    mov rcx, 0xc0000101
+    mov rax, 0xbbbbbbbb
+    call wrmsr
+
+    // Setup IA32_KERNEL_GS_BASE.
+    mov rcx, 0xc0000102
+    mov rax, 0xaaaaaaaa
+    call wrmsr
+
+    // Print IA32_GS_BASE.
+    pstr gsbase
+    mov rcx, 0xc0000101
+    call rdmsr
+    call pu64
+
+    // Print IA32_KERNEL_GS_BASE.
+    pstr kgsbase
+    mov rcx, 0xc0000102
+    call rdmsr
+    call pu64
+
+    pstr swapgs
+    // Swap IA32_GS_BASE and IA32_KERNEL_GS_BASE.
+    swapgs
+
+    // Print IA32_GS_BASE.
+    pstr gsbase
+    mov rcx, 0xc0000101
+    call rdmsr
+    call pu64
+
+    // Print IA32_KERNEL_GS_BASE.
+    pstr kgsbase
+    mov rcx, 0xc0000102
+    call rdmsr
+    call pu64
+
+    // Trigger `KVM_EXIT_HLT`.
+    hlt
+
+// in : ecx address of msr register
+// out: rax value of msr register
+rdmsr:
+    rdmsr
+    shl rdx, 32
+    or rax, rdx
+    ret
+
+// in: ecx address of msr register
+// in: rax value to write into msr register
+wrmsr:
+    mov rdx, rax
+    shr rdx, 32
+    wrmsr
+    ret
+
+// in: rax holds 64bit word to be printed
+pu64:
+    xor dx, dx     // Port to print values.
+    out dx, eax    // Print lower-half (u32) of rax.
+    //shr rax, 32
+    //out dx, eax    // Print upper-half (u32) of rax.
+    ret
+
+.section .rodata, "a", @progbits
+defstr fsbase,  "fsbase: "
+defstr gsbase,  "gsbase: "
+defstr kgsbase, "kernel_gsbase: "
+defstr swapgs,  "-- swapgs --\n"
diff --git a/guest/guest64.S b/guest/guest64.S
index 1ca91a5..dc3e986 100644
--- a/guest/guest64.S
+++ b/guest/guest64.S
@@ -2,7 +2,7 @@
 
 .section .boot, "ax", @progbits
     // Trigger `KVM_EXIT_IO:KVM_EXIT_IO_OUT` by writing string to output port.
-    mov rdx, 0x1000             // Output port.
+    mov rdx, 0x42               // Output port (magic for string fmt).
     lea rsi, [rip + msg]        // Address of string.
     mov rcx, [rip + msg_len]    // Len of string.
     rep outsb                   // Write ds:rsi to output port rdx.
@@ -30,7 +30,7 @@
 
 .section .rodata, "a", @progbits
 msg:
-    .asciz "Hello from Long Mode!\n"
+    .ascii "Hello from Long Mode!\n"
 msg_len:
     .byte .-msg